사용자 도구

사이트 도구

English

clcd와_연결:index

CLCD와 연결

CLCD는 FA-DUINO와 연결할 수 있는 캐릭터 LCD 모듈입니다.

I2C를 이용해서 CLCD와 연결합니다. 다음 결선도를 보고 연결하십시오. 이때 CLCD모듈의 딥스위치를 모두 OFF 위치로 하여, 슬레이브 어드레스를 0으로 맞추어주 십시오.

다음 소스로 CLCD에 문자를 표시할 수 있습니다.

#include    <Wire.h>
#define     ADDR_CLCD             0
 
unsigned char   locate_x;
unsigned char   locate_y;
 
void clcd_clear             ();
void clcd_cursor_visible    (bool enable);
void clcd_backLight_enable  (bool enable);
void clcd_print             (String value);
void clcd_locate            (unsigned char x, unsigned char y);
 
void setup() {
  Wire.begin();                     // 마스터모드로 동작
  Wire.setClock(500000);            // 500 kHz.
  clcd_clear();                     // 화면 전채를 지움
  clcd_cursor_visible(false);       // 커서 설정
  clcd_backLight_enable(true);      // 백라이트 설정
  clcd_locate(0,4);                 // 문자 표시 위치
  clcd_print("COMFILE_TECH");       // 문자 표시
  clcd_locate(2,5);
  clcd_print("0123456789");
}
 
void loop() {
}
 
void clcd_clear(){
  unsigned char tmp_buf[] = {0x1b,0x43};
  Wire.beginTransmission(ADDR_CLCD);
  Wire.write(tmp_buf,2);
  Wire.endTransmission();
  delay(200);
}
 
void clcd_cursor_visible(bool enable){
  unsigned char tmp_buf[] = {0x1b,enable == true ? 0x53 : 0x73};
  Wire.beginTransmission(ADDR_CLCD);
  Wire.write(tmp_buf,2);
  Wire.endTransmission();
}
void clcd_backLight_enable(bool enable){
  unsigned char tmp_buf[] = {0x1b,enable == true ? 0x42 : 0x62};
  Wire.beginTransmission(ADDR_CLCD);
  Wire.write(tmp_buf,2);
  Wire.endTransmission();
}
 
void clcd_locate(unsigned char x, unsigned char y){
  locate_x = x;
  locate_y = y;
}
 
void clcd_print(String value){
  unsigned char tmp_buf[] = {0x1b,0x4b,locate_y,locate_x,locate_y,locate_x};
  Wire.beginTransmission(ADDR_CLCD);
  Wire.write(tmp_buf,6);
  Wire.write(value.c_str());
  Wire.write(0);
  Wire.endTransmission();
}

산업용 아두이노 FA-DUINO

clcd와_연결/index.txt · 마지막으로 수정됨: 2019/04/02 18:14 저자 Comfile Technology